使用一个简单的 XSL 样式表就可以将 XML 数据转换成 HTML。随着 XML 规范的不断演进，在新的版本中满足每个人的需要似乎已经成为必要；不幸的是，进行简单的转换一直都困扰着规范。
　　
　　假设我有一个表示一个页面内容的 XML　数据，现在我想将其内容转换成布局。下面是我想要转换的 XML：

　　<?xml version='1.0'?>
　　<?xml-stylesheet type="text/xsl" href="article.xsl"?>
　　<xml>
　　    <folders>
　　        <folder>
　　            <text>Folder 1</text>
　　            <files>
　　                <file>
　　                    <text>File 1</text>
　　                    <fields>
　　                        <field>
　　                            <data>
　　                                <type>string</type>
　　                                <length>50</length>
　　                                <value>some data</value>
　　                            </data>
　　                        </field>
　　                    </fields>
　　                </file>
　　            </files>
　　        </folder>
　　    </folders>
　　</xml>

　　这个内容表示一组文件夹、文件和域。每个文件夹包含文件，每个文件包含用于输入数据的域。文件夹组中的每个文件夹都将表现为一个 TABLE 的第一行的一个 TR 元素和一个 TD 元素。文件组中的每个文件都将表示为嵌套在文件夹 TR 元素中的一个 TABLE 元素的第一行的一个 TR 元素和一个 TD 元素。域组中的每个域都将在相关的文件中表现为一个 INPUT。

　　为了实现这一想法，我们需要将遍历 XML 然后根据XSL 构建一个表。

　　下面是用于这个转换的 XSL：

　　<?xml version="1.0"?>
　　<xsl:stylesheet
　　    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
　　    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
　　    xmlns:fn="http://www.mycompany.com/mynamespace">
　　<xsl:output method="html"/>

　　<msxsl:script language="JScript" implements-prefix="fn">
　　    function getElementCount(nodelist, what) {
　　        var rtrn = 0;
　　        rtrn = nodelist[0].parentNode.selectNodes(what).length;
　　        return (rtrn + 1); //1 is added for filler TD
　　    }
　　</msxsl:script>

　　<xsl:template match="/">

　　<TABLE CELLSPACING="0" CELLPADDING="0"
　　    WIDTH="100%" BORDER="0" ID="tblRoot" NAME="tblRoot"
　　    style="table-layout:fixed;">
　　    <TR>
　　        <xsl:for-each select="xml/folders/folder">
　　        <xsl:element name="TD">
　　            <xsl:attribute name="style">width:55px</xsl:attribute>
　　            <xsl:value-of select="text"/>
　　        </xsl:element>
　　        </xsl:for-each>
　　        <TD> </TD>
　　    </TR>

　　    <xsl:for-each select="xml/folders/folder">
　　    <TR>
　　        <xsl:element name="TD">
　　            <xsl:attribute name="colspan">
　　                <xsl:value-of select="fn:getElementCount(., 'folder')"/>
　　            </xsl:attribute>
　　               
　　            <TABLE CELLSPACING="0" CELLPADDING="0"
　　                WIDTH="100%" BORDER="0" style="table-layout:fixed;">
　　                <TR>
　　                    <xsl:for-each select="files/file">
　　                    <xsl:element name="TD">
　　                        <xsl:attribute name="style">width:55px;</xsl:attribute>
　　                        <xsl:value-of select="text"/>
　　                    </xsl:element>
　　                    </xsl:for-each>
　　                    <TD> </TD>
　　                </TR>

　　                <xsl:for-each select="files/file">
　　                    <TR>
　　                        <xsl:element name="TD">
　　                            <xsl:attribute name="colspan">
　　                                <xsl:value-of select="fn:getElementCount(., 'file')"/>
　　                            </xsl:attribute>

　　                        <xsl:for-each select="fields/field">
　　                        <xsl:element name="INPUT">
　　                            <xsl:attribute name="type">text</xsl:attribute>
　　                            <xsl:attribute name="maxlength">
　　                                <xsl:value-of select="data/length"/>
　　                            </xsl:attribute>
　　                            <xsl:attribute name="value">
　　                                <xsl:value-of select="data/value"/>
　　                            </xsl:attribute>
　　                        </xsl:element><BR/>
　　                        </xsl:for-each>

　　                        </xsl:element>
　　                    </TR>
　　                </xsl:for-each>
　　            </TABLE>
　　        </xsl:element>
　　    </TR>
　　    </xsl:for-each>
　　</TABLE>

　　</xsl:template>
　　</xsl:stylesheet>
　　在 stylesheet 标记中，我们设置了几个命名空间，包括定义所有 xsl 转换标记的 xsl 命名空间。能够让我们创建可以在样式表中使用的用户函数的msxml 命名空间。我使用它得到所有的子元素，以便得到一个 TD 标记的一个 COLSPAN 属性集。用于加入一组用户定义的函数的fn 命名空间，该命名空间由msxml:script element 创建。

　　 
　　然后，我们创建外部 TABLE 和第一个 TR。在 TR 中，我为 XML 中指定的每个文件夹创建一个 TD。我使用了 xsl:element 标记，因为它允许我添加自定义属性或者执行一个函数来为另一个 TD 元素中的 COLSPAN 属性设置一个属性。

　　在为每个文件夹创建了所需的 TD 之后，我开始为每个文件夹创建 TR。我只向这个 TR 添加一个 TD，但是我将它的 COLSPAN 属性设为等于文件夹组中文件夹标记的数量再加一。多出的一是用来在一个固定布局样式的 TABLE 中填充空格用的。

　　为了得到 COLSPAN，我传入当前的上下文（在这里由“.”指定）和我想计算的节点的名字。在我的函数中，我得到当前的上下文，paraentNode，和 XPath 查询中指定的节点的数量。然后函数返回这个数量加上一以填充 TD。

　　有了这个 TD，我在其中嵌入另外一个 TABLE，该 TABLE 包含文件组中的每个文件。从这一点开始，其过程就与外部 TABLE 转换一样。最后的步骤是添加每个文件中的域。这次我没有再创建嵌入的 TABLE，只是把这些域添加到当前的 TD 中。

　　一旦我完成了通用布局，我就可以开始添加用户界面功能了，比如说隐藏掉其它的文件夹和文件行，直到用户点击了相关的选项卡。这一功能可以通过编写支持这一功能的脚本来实现，添加一个 onclick xsl:attribute 元素到文件夹和文件 TD 元素，然后将它的值设置为脚本函数的名字。

　　最后，在通用功能完成之后，你可以添加class xsl:attributes 并在 STYLE 或 CSS 中添加相关的classNames 得到你想要的外观。

　　这个例子为在部署 Web 数据解决方案中用到的 File-Folder-Field 视图创建了一个基础。访问 MSDN 找到更多有关Microsoft 的 XML 规范的信息。