注意：本文章的示例程序所用的东西不超过GDI的范围。
　　在图像处理中，速度是很重要的。因此，我们得重新处理一下TBitmap,得到TVczhBitmap。这只是因为GetPixels和SetPixels的速度太慢，换一个方法而已。
　　unit untBitmapProc;
　　interface
　　uses Graphics, SysUtils;
　　type
　　TVczhBitmap=class(TBitmap)
　　private
　　Data:PByteArray;
　　Line:Integer;
　　procedure SetFormat;
　　function GetBytePointer(X,Y:Integer):PByte;
　　procedure SetBytes(X,Y:Integer;Value:Byte);
　　function GetBytes(X,Y:Integer):Byte;
　　protected
　　published
　　constructor Create;
　　public
　　property Bytes[X,Y:Integer]:Byte read GetBytes write SetBytes;
　　procedure LoadFromFile(FileName:String);
　　procedure ToGray;
　　end;
　　implementation
　　procedure TVczhBitmap.SetFormat;
　　begin
　　HandleType:=bmDIB;
　　PixelFormat:=pf24bit;
　　end;
　　function TVczhBitmap.GetBytePointer(X,Y:Integer):PByte;
　　begin
　　if Line<>Y then
　　begin
　　Line:=Y;
　　Data:=ScanLine[Y];
　　end;
　　Longint(result):=Longint(Data)+X;
　　end;
　　procedure TVczhBitmap.SetBytes(X,Y:Integer;Value:Byte);
　　begin
　　GetBytePointer(X,Y)^:=Value;
　　end;
　　function TVczhBitmap.GetBytes(X,Y:Integer):Byte;
　　begin
　　result:=GetBytePointer(X,Y)^;
　　end;
　　constructor TVczhBitmap.Create;
　　begin
　　inherited Create;
　　SetFormat;
　　Line:=-1;
　　end;
　　procedure TVczhBitmap.LoadFromFile(FileName:String);
　　begin
　　inherited LoadFromFile(FileName);
　　SetFormat;
　　Line:=-1;
　　end;
　　procedure TVczhBitmap.ToGray;
　　var X,Y,R:Integer;
　　B:Byte;
　　begin
　　for Y:=0 to Height-1 do
　　for X:=0 to Width-1 do
　　begin
　　R:=0;
　　for B:=0 to 2 do
　　R:=R+GetBytes(X*3+B,Y);
　　for B:=0 to 2 do
　　SetBytes(X*3+B,Y,R div 3);
　　end;
　　end;
　　end.
　　此后，我们需要建立几个窗体。第一个用来显示图片，第二个用来处理图片，其他的窗体都继承自第二个窗体，包含实际的处理方法。
　　先看第二个窗口：
　　unit untProc;
　　interface
　　uses
　　Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
　　Dialogs, ExtCtrls, untBitmapProc, StdCtrls, ComCtrls;
　　type
　　TfrmProcessor = class(TForm)
　　pbBar: TPaintBox;
　　gpProc: TGroupBox;
　　Button1: TButton;
　　procedure FormCreate(Sender: TObject);
　　procedure FormDestroy(Sender: TObject);
　　procedure FormShow(Sender: TObject);
　　procedure pbBarPaint(Sender: TObject);
　　procedure Button1Click(Sender: TObject);
　　private
　　{ Private declarations }
　　public
　　{ Public declarations }
　　BarData:array[0..255]of Byte;
　　Bar:TVczhBitmap;
　　procedure DrawBar;
　　end;
　　var
　　frmProcessor: TfrmProcessor;
　　implementation
　　{$R *.dfm}
　　uses untViewer;
　　procedure TfrmProcessor.DrawBar;
　　var I:Integer;
　　begin
　　Bar.Canvas.FillRect(Bar.Canvas.ClipRect);
　　Bar.Canvas.MoveTo(0,255-BarData[0]);
　　for I:=1 to 255 do
　　Bar.Canvas.LineTo(I,255-BarData[I]);
　　end;
　　procedure TfrmProcessor.FormCreate(Sender: TObject);
　　begin
　　Bar:=TVczhBitmap.Create;
　　Bar.Width:=256;
　　Bar.Height:=256;
　　Bar.Canvas.Brush.Color:=clWhite;
　　Bar.Canvas.Brush.Style:=bsSolid;
　　end;
　　procedure TfrmProcessor.FormDestroy(Sender: TObject);
　　begin
　　Bar.Free;
　　end;
　　procedure TfrmProcessor.FormShow(Sender: TObject);
　　var I:Integer;
　　begin
　　for I:=0 to 255 do
　　BarData[I]:=I;
　　DrawBar;
　　end;
　　procedure TfrmProcessor.pbBarPaint(Sender: TObject);
　　begin
　　pbBar.Canvas.Draw(0,0,Bar);
　　end;
　　procedure TfrmProcessor.Button1Click(Sender: TObject);
　　var X,Y:Integer;
　　begin
　　for Y:=0 to Buffer.Height-1 do
　　for X:=0 to Buffer.Width*3-1 do
　　Played.Bytes[X,Y]:=BarData[Buffer.Bytes[X,Y]];
　　frmViewer.FormPaint(frmViewer);
　　end;
　　end.
　　之后，做一个窗口继承自它，则调整BarData[]后，按Apply即可看到结果。
　　现在开始将图像处理。具体效果见示例程序。
　　
　　一、颜色反转。
　　灰度图像的颜色都是从0~255，所以，为了使颜色反转，我们可以用255减去该颜色值以得到反转后的颜色。
　　var I:Integer;
　　begin
　　inherited;
　　for I:=0 to 255 do
　　BarData[I]:=255-I;//用255减去该颜色值
　　DrawBar;
　　pbBarPaint(pbBar);
　　end;
　　
　　二、缩小颜色范围以增强或减弱亮度
　　颜色本来是从0~255的。如果调节它的范围，例如从0~16，则会是图像明显变暗。我们可以把起始值设为a，把终止值设为b，则新的颜色值New=a+(b-1)*Old/255。这样做的话可以改变亮度，并且不会破坏原先颜色的顺序。代码如下
　　var I:Integer;
　　begin
　　for I:=0 to 255 do
　　BarData[I]:=(255-sbMin.Position)+Round((sbMin.Position-sbMax.Position)/255*I);
　　DrawBar;
　　pbBarPaint(pbBar);
　　Button1Click(Button1);
　　end;
　　这里的sbMin.Position和sbMaxPosition都是反转过的。所以使用时要用255去减
　　
　　三、增加某个范围内的颜色范围
　　如果图像本身的颜色范围很小的画，你可以通过这种方法来加大图像的对比度，有利于对图像的分析。具体做法：
　　选取一个值a做为起始值，选取一个值b做为终止值，然后按以下公式变形：
　　|　0 (X<=a)
　　f(X)= |　255/(b-a)*(X-a)
　　|　255(X>=b)
　　var I:Integer;
　　begin
　　for I:=0 to 255 do
　　begin
　　if I<=sbMin.Position then
　　BarData[I]:=0
　　else if I>=sbMax.Position then
　　BarData[I]:=255
　　else
　　BarData[I]:=Round(255/(sbMax.Position-sbMin.Position)*(I-sbMin.Position));
　　end;
　　DrawBar;
　　pbBarPaint(pbBar);
　　Button1Click(Button1);
　　end;
　　
　　四、变为黑白图片
　　在使用第三个功能的时候，你会发现当b<=a时，图像上的颜色除了黑色就是白色。这样操作的好处是不能直接显示出来的。这只要到了比较高级的图像处理如边缘检测等，才有作用。本例可以拿第三种方法的公式再变形，因此不作详细阐述。
　　
　　五、指数级亮度调整
　　

　　我们假设这个图的定义域是[0,1]，值域也是[0,1]。那么，定义函数f(x)=x^c，则f(x)的图像有一段如上图。我们再用鼠标操作时，可以在上面取一点P(a,b)，然后使f(x)通过点P，则c=ln(b)/ln(a)。有了c之后，我们就可以对颜色进行操作了：
　　New=(Old/255)^c*255=exp(ln(old/255)*c)*255
　　var ea,eb,ec:Extended;
　　I:Integer;
　　begin
　　ea:=A/255;
　　eb:=B/255;
　　ec:=Ln(eb)/Ln(ea);
　　for I:=1 to 255 do
　　BarData[I]:=Round(Exp(Ln((I/255))*ec)*255);
　　DrawBar;
　　pbBarPaint(pbBar);
　　Button1Click(Button1);
　　end;
　　这样做可以调节图像的亮度。